mirror of
https://github.com/yacy/yacy_search_server.git
synced 2024-09-19 00:01:41 +02:00
a5771b1f14
TLS Server Name Indication (SNI) extension activation can now be configured with the new Settings_p.html?page=httpClient administration page. SNI extension is also now enabled by default, as in 2019 the unrecognized_name(112) alert is more properly handled by major web servers TLS implementations, following the RFC 6066 standard. Related YaCy issues : #153 #189 and #272 JDK 1.7 bug : https://bugs.java.com/bugdatabase/view_bug.do?bug_id=7127374 Apache httpd issue : https://bz.apache.org/bugzilla/show_bug.cgi?id=56241 RFC 6066 : https://tools.ietf.org/html/rfc6066#section-3
78 lines
2.8 KiB
Batchfile
78 lines
2.8 KiB
Batchfile
@Echo Off
|
|
title YaCy
|
|
|
|
if exist DATA\yacy.noconsole del DATA\yacy.noconsole
|
|
|
|
Rem Generating the proper classpath unsing loops and labels
|
|
Set CLASSPATH=lib/yacycore.jar
|
|
|
|
REM Please change the "javastart" settings in the web-interface "Basic Configuration" -> "Advanced"
|
|
set jmx=
|
|
set jms=
|
|
set javacmd=-Xmx600m -Xms180m
|
|
set priolvl=10
|
|
set priority=/BELOWNORMAL
|
|
set port=8090
|
|
if exist DATA\SETTINGS\httpProxy.conf GoTo :RENAMEINDEX
|
|
if exist DATA\SETTINGS\yacy.conf GoTo :GETSTARTOPTS
|
|
|
|
:STARTJAVA
|
|
set javacmd=%javacmd% -XX:-UseGCOverheadLimit -Djava.awt.headless=true -Dfile.encoding=UTF-8
|
|
|
|
Rem Starting YaCy
|
|
Echo Generated classpath:%CLASSPATH%
|
|
Echo JRE Parameters:%javacmd%
|
|
Echo Priority:%priority%
|
|
|
|
Echo ****************** YaCy Web Crawler/Indexer ^& Search Engine ******************
|
|
Echo **** (C) by Michael Peter Christen, usage granted under the GPL Version 2 ****
|
|
Echo **** USE AT YOUR OWN RISK! Project home and releases: http://yacy.net/ ****
|
|
Echo ** LOG of YaCy: DATA/LOG/yacy00.log (and yacy^<xx^>.log) **
|
|
Echo ** STOP YaCy: execute stopYACY.bat and wait some seconds **
|
|
Echo ** GET HELP for YaCy: see www.yacy-websearch.net/wiki and forum.yacy.de **
|
|
Echo *******************************************************************************
|
|
Echo ^>^> YaCy started as daemon process. Administration at http://localhost:%port% ^<^<
|
|
|
|
title YaCy - http://localhost:%port%
|
|
|
|
Rem commandline parameter added for -config option, like -config "port=8090" "adminAccount=admin:password"
|
|
Rem special parameter "adminAccount=admin:password" calculates and sets new admin-pwd
|
|
Rem any parameter in yacy.conf can me modified this way (make sure to use correct upper/lower case)
|
|
|
|
start "YaCy" %priority% /B /WAIT java %javacmd% -classpath %CLASSPATH% net.yacy.yacy %1 %2 %3 %4 %5 %6 %7 %8 %9
|
|
|
|
if not exist DATA\yacy.restart GoTo :END
|
|
del DATA\yacy.restart
|
|
GoTo :GETSTARTOPTS
|
|
|
|
Rem PUBLIC is now freeworld (r4575)
|
|
:RENAMEINDEX
|
|
for /F "tokens=1,2 delims==" %%i in (DATA\SETTINGS\httpProxy.conf) do (
|
|
if "%%i"=="network.unit.name" set networkname=%%j
|
|
)
|
|
if not defined networkname set networkname=PUBLIC
|
|
cd DATA\INDEX
|
|
ren PUBLIC %networkname%
|
|
cd ..
|
|
cd ..
|
|
|
|
Rem This target is used to read java runtime parameters out of the yacy config file
|
|
:GETSTARTOPTS
|
|
for /F "tokens=1,2 delims==" %%i in (DATA\SETTINGS\yacy.conf) do (
|
|
if "%%i"=="javastart_Xmx" set jmx=%%j
|
|
if "%%i"=="javastart_Xms" set jms=%%j
|
|
if "%%i"=="port" set port=%%j
|
|
if "%%i"=="javastart_priority" set priolvl=%%j
|
|
)
|
|
if defined jmx set javacmd=-%jmx%
|
|
if defined jms set javacmd=-%jms% %javacmd%
|
|
if defined priolvl (
|
|
if %priolvl% == 20 set priority=/LOW
|
|
if %priolvl% == 10 set priority=/BELOWNORMAL
|
|
)
|
|
|
|
GoTo :STARTJAVA
|
|
|
|
Rem Target needed to jump to the end of the file
|
|
:END
|